写了个Vista的服务优化脚本

---

自己经常关掉vista里边的一些用不到的服务,节省些内存,手工改太麻烦,今晚花了点时间做了个自动优化还原的脚本

可以自动禁止不需要的服务
可以恢复vista安装时候的默认设置

需要管理员权限运行

特色:可以通过修改服务列表方便的进行扩充,可以轻易的移植到xp

@echo off
goto start
:Copyright
echo -----------------------------------------
echo - -
echo - Windows Vista Home Basic -
echo - Service Optimization Tools -
echo - -
echo - Copyright y97523[BCG] -
echo - china 2007-3-11 -
echo - -
echo -----------------------------------------
echo please run this as Administor!
echo.
GOTO :EOF

:start
:init
set svrlst=svr.lst

echo ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;>%svrlst%
echo ;;sevice name,start type(auto,demand,delayed-auto) ;;>>%svrlst%
echo ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;>>%svrlst%
echo DPS,auto >>%svrlst%
echo ;WdiSystemHost,demand >>%svrlst%
echo TrkWks,auto >>%svrlst%
echo IKEEXT,auto >>%svrlst%
echo iphlpsvc,auto >>%svrlst%
echo PolicyAgent,auto >>%svrlst%
echo WPDBusEnum,auto >>%svrlst%
echo Spooler,auto >>%svrlst%
echo EMDMgmt,auto >>%svrlst%
echo LanmanServer,auto >>%svrlst%
echo ;SSDPSRV,demand >>%svrlst%
echo TabletInputService,auto >>%svrlst%
echo lmhosts,auto >>%svrlst%
echo ;TapiSrv,demand >>%svrlst%
echo WebClient,auto >>%svrlst%
echo WerSvc,auto >>%svrlst%
echo stisvc,auto >>%svrlst%
echo LanmanWorkstation,auto >>%svrlst%
echo W3SVC,auto >>%svrlst%
rem type %svrlst%

:choise
cls
call :Copyright
echo Please Select your Choise
set /p choise= Optimization Service(O)/Restore Default Service Setting(R)/Exit(X):
if /i "%choise%" == "o" goto Optimization
if /i "%choise%" == "r" goto restore
if /i "%choise%" == "x" goto exit
goto choise

:Optimization
echo ------Start Optimization Service------
for /f "eol=; tokens=1,2* delims=," %%i in (%svrlst%) do echo %%i: &&sc config "%%i" start= disabled
echo.
echo ------Optimization Completed,Check Any Error------
echo push any key to return!
pause >nul
goto choise

:restore
echo ------Restore Default Service------
for /f "eol=; tokens=1,2* delims=," %%i in (%svrlst%) do echo %%i: &&sc config "%%i" start= %%j
echo.
echo ------Restore Completed,Check Any Error------
echo push any key to return!
pause >nul
goto choise

:exit
del %svrlst% /q

---

« 
» 

---